CASS9怎么通过lsp文件把文字生成数据文件？

可以通过自定义的lsp文件来实现。

1.     打开CASS软件，在命令行中键入“VLISP”命令，打开“lsp交互式开发环境”，点击“新建”按钮。

2.     复制粘贴以下的代码

 (defun c:tqsz()

  (setq drawm0 (getvar "userr1"))

  (if (= drawm0 0)

    (setq drawm0 (getreal "\n 绘图比例尺1: <500>："))

  )

  (if (= drawm0 nil) (setq drawm0 500.0))

  (setvar "userr1" drawm0)

  (setq drawscl (/ drawm0 1000))

  (setq wy (* drawscl 1.5))

  (setq wx (* drawscl 1))

  (princ"\n 请选择要提取的数字:")

  (setq ss (ssget '((0 . "TEXT") (1 . "~*[~`--9]*"))))

  (princ "\n")

  (setq ffn (getfiled "写出文件" "" "dat" 1))

  (setq ff (open ffn "w"))

  (setq i 0)

  (repeat (sslength ss)

    (setq ssn (ssname ss i))

    (setq ssdata (entget ssn))

    (setq endata (cdr (assoc 10 ssdata)))

    (setq z (cdr (assoc 1 ssdata)))

    (setq y (- (car endata) wy))

    (setq x (+ (cadr endata) wx))

    (setq i (1+ i))

    (setq text (strcat (rtos i 2 0) ",," (rtos y 2 3) "," (rtos x 2 3) "," z))

    (write-line text ff)      

  )

  (close ff)

  (princ (strcat "\n文件保存位置==>: " ffn))

  (princ "\n本次总共提取了 ") (princ i) (princ " 个高程点")

  (prin1)

)

(princ "\n====键入 tqsz 运行本插件")

3.     点击“保存”按钮，命名为“纯数字生成高程点数据(tqsz).lsp”

4.     打开CASS软件，在命令行中键入“APPLOAD”，打开“加载/卸载应用程序”对话框。选择“纯数字生成高程点数据(tqsz).lsp”，并点击“加载”按钮。

5.     消息框提示加载成功。

6.     点击“关闭”按钮，关闭当前对话框。

7.     在CASS命令行中，键入“tqsz”命令，根据命令行提示选择文字对象，回车确认，指定保存路径。

8.     命令行打印出生成成功的提示信息。

9.     打开生成的dat文件，查看结果。